File:Hailwood-Horrobin EMC graph.svg

Page contents not supported in other languages.
This is a file from the Wikimedia Commons
From Wikipedia, the free encyclopedia

Original file ‎(SVG file, nominally 480 × 320 pixels, file size: 17 KB)

Summary

Description
English: Equilibrium moisture content of wood versus relative humidity of the surrounding air.
Date
Source Own work
Author Hankwang
SVG development
InfoField
 
The SVG code is valid.
 
This chart was created with Gnuplot.
 
This chart uses translateable embedded text.
Source code
InfoField
Gnuplot code
# Gnuplot script to generate EMC plot, for Gnuplot version 4.2.
# Author: User hankwang on Wikipedia (2010).
# Equations taken from the Wikipedia article as of 2010-12-31.
# TF = temperature in deg F, TC = temp. in deg C

W(TF)  = 330   + 0.452*TF  + 0.00415*TF**2
k(TF)  = 0.791 + 4.63e-4*TF - 8.44e-7*TF**2
k1(TF) = 6.34  + 7.75e-4*TF - 9.35e-5*TF**2
k2(TF) = 1.09  + 2.84e-2*TF - 9.04e-5*TF**2

emcx(TF,k1,k2,kh)=1800./W(TF)  * (kh/(1-kh)  + (k1*kh+2*k1*k2*kh**2)/(1+k1*kh+k1*k2*kh**2))

emcF(TF,h)=emcx(TF,k1(TF),k2(TF),k(TF)*h)

C2F(TC)=TC*1.8+32
F2C(TF)=(TF-32)*5.0/9

emcC(TC,h)=emcF(C2F(TC),h)

set xlab 'Relative humidity (%)'
set xra [0:100]
set ylab 'EMC (%)'
set key top left

set term svg enhanced size 480,320
set outp 'emc.svg'

plot \
    emcC(0,x*0.01)   ti '0 ^oC (32 ^oF)' lt -1 lw 2, \
    emcC(30,x*0.01)  ti '30 ^oC (86 ^oF)' lt 3 lw 2, \
    emcC(60,x*0.01)  ti '60 ^oC (140 ^oF)' lt 2 lw 2, \
    emcC(120,x*0.01) ti '120 ^oC (248 ^oF)' lt 1 lw 2

set outp

Licensing

I, the copyright holder of this work, hereby publish it under the following licenses:
w:en:Creative Commons
attribution share alike
This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
You are free:
  • to share – to copy, distribute and transmit the work
  • to remix – to adapt the work
Under the following conditions:
  • attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
  • share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
GNU head Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.
You may select the license of your choice.

Captions

Add a one-line explanation of what this file represents

Items portrayed in this file

depicts

inception

31 December 2010

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current09:17, 31 December 2010Thumbnail for version as of 09:17, 31 December 2010480 × 320 (17 KB)Hankwang{{Information |Description={{en|1=Equilibrium moisture content of wood versus relative humidity of the surrounding air. }} |Source={{own}} |Author=Hankwang |Date=2010-12-31 |Permission= |other_version
The following pages on the English Wikipedia use this file (pages on other projects are not listed):

Global file usage

The following other wikis use this file:

Metadata

This file contains additional information, probably added from the digital camera or scanner used to create or digitize it.

If the file has been modified from its original state, some details may not fully reflect the modified file.

Retrieved from "https://en.wikipedia.org/wiki/File:Hailwood-Horrobin_EMC_graph.svg"